2013年9月22日 星期日

Excel-偶數,奇數之運用

在 Excel 中要判斷一個數是偶數或是奇數,常用的方式不外以下數種:(以判斷儲存格A1為例)

(1) 公式 =IF(ISEVEN(A1),"偶數","奇數")

ISEVEN 函數判斷是否為偶數(傳回 True/False),ISODD 函數判斷是否為奇數(傳回 True/False)。

(2) 公式 =IF(MOD(A1,2)=0,"偶數","奇數")

使用 MOD 函數來求儲存格A1除以 2 的餘數,結果為 0,傳回「偶數」,否則,傳回「奇數」。

(3) 公式 =IF(INT(A1/2)=A1/2,"偶數","奇數")

使用 IND 函數來求儲存格A1除以 2 的商取不大於的最大整數,是否和儲存格A1除以 2 的結果相等,結果為 0,傳回「偶數」,否則,傳回「奇數」。

(4) 公式 =IF(QUOTIENT(A1,2)=A1/2,"偶數","奇數")

使用 QUOTIENT 函數來求儲存格A1除以 2 的整數商,是否和儲存格A1除以 2 的結果相等,結果為 0,傳回「偶數」,否則,傳回「奇數」。

利用偶數/奇數的判斷,可以用在那些地方呢?

參考下圖來做些練習:

選取儲存格A1:B21,按一下 Ctrl+Shift+F3 鍵,勾選「頂端列」,定義名稱:序號、數值。

藉由 SUMPRODUCT 函數來求以下四項:

(1) 偶數列數值和

儲存格E2:=SUMPRODUCT((MOD(序號,2)=0)*數值)

(2) 奇數列數值和

儲存格E3:=SUMPRODUCT((MOD(序號,2)=1)*數值)

(3) 偶數數值之和

儲存格E4:=SUMPRODUCT((MOD(數值,2)=0)*數值)

(4) 奇數數值之和

儲存格E5:=SUMPRODUCT((MOD(數值,2)=1)*數值)

接著來設定序號欄位和數值欄位的格式:

(1) 數值欄位偶數者,字型顯示藍色粗體

選取儲存格B2:B21,設定格化式的條件,使用公式來決定要格式化哪些儲存格。

規則:=MOD(B2,2)=0,格式:字型為藍色粗體。

(2) 序號為奇數者,整列改為粉紅色底色

選取儲存格A2:B21,設定格化式的條件,使用公式來決定要格式化哪些儲存格。

規則:=MOD($A2,2)=1,格式:填滿粉紅色底色。

 

接著來練習進一步的應用。

原始格式:

設定格式:

選取儲存格A1:I10,設定格式條件,使用公式來決定要格式化哪些儲存格。

(1) 公式:=(MOD(ROW(A1),2)=0)*(MOD(COLUMN(A1),2)=1)

公式中的「*」乃將二個條件作「AND」運算。找出偶數列和奇數欄的交集。

(2) 公式:=(MOD(ROW(A1),2)=1)*(MOD(COLUMN(A1),2)=0)

找出奇數列和偶數欄的交集。

格式:較淺粉紅色底色。

選取儲存格A1:I10,設定格式條件,使用公式來決定要格式化哪些儲存格。

(3) 公式:=(MOD(ROW(A1),2)=1)*(MOD(COLUMN(A1),2)=0)

找出奇數列和偶數欄的交集。

(4) 公式:=(MOD(ROW(A1),2)=0)*(MOD(COLUMN(A1),2)=1)

找出偶數列和奇數欄的交集。

格式:紅色粗體字型。

沒有留言:

張貼留言

檢視其他文章

好康東東