2017年12月17日 星期日

Excel-無條件進位、無條件捨、四捨五入至5的倍數(ROUNDUP,ROUNDDOWN,MROUND)

網友根據前一篇文章:Excel-無條件進位至5的倍數(INT,MOD),提供了其他做的做法。
前一篇文章比較像是利用運算思維的角度,以 INT 和 MOD 函數來解決問題。如果你要使用現有的函數來處理也是可以。
Excel-無條件進位、無條件捨、四捨五入至5的倍數(ROUNDUP,ROUNDDOWN,MROUND)

【公式設計與解析】
原公式:
=INT(A2/10)*10+(MOD(A2,10)>5)*10+(MOD(A2,10)>0)*(MOD(A2,10)<=5)*5
若使用 ROUNDUP、ROUNDDOWN、MROUND 等函數,可以縮短公式。
1. 無條件進位至5的倍數
儲存格B2:=ROUNDUP(A2/5,0)*5
2. 無條件捨去至5的倍數
儲存格C2:=ROUNDDOWN(A2/5,0)*5
3. 四捨五入至5的倍數
儲存格D2:=MROUND(A2,5)
複製儲存格B2,貼至儲存格B2:D22。

2017年12月16日 星期六

Excel-根據數值清單計算累計和排名前幾個的總和(SUMPRODUCT,OFFSET)

(網友提問)在 Excel 的工作表中有個數值清單(參考下圖左),如何根據數值清單計算累計前幾個的總和,及排名前幾個的總和?
image

【公式設計與解析】
選取儲存格A1:D24,按 Ctrl+Shift+F3 鍵,勾選「頂端列」,定義名稱:序號、數值、累計、排名。
1. 累計前n個總和
儲存格G2:=SUM(OFFSET($B$2,0,0,G1,1))
複製儲存格G2,貼至儲存格G2:I2。
OFFSET($B$2,0,0,G1,1):根據儲存格G1的內容,傳回從儲存格B2起始的儲存格範圍。
再利用 SUM 函數計算總和。

2. 排名前n個總和(*使用D欄)
儲存格G3:=SUMPRODUCT(數值*(排名<=G1))
複製儲存格G3,貼至儲存格G3:I3。
在 SUMPRODUCT 函數中先判斷每個數值的名次是否小於儲存格G1,若是傳回 TRUE,若否,則傳回 FALSE。再於 SUMPRODUCT 函數中計算對應的數值總和。

3. 排名前n個總和(*不使用D欄)
儲存格G3:=SUMPRODUCT(數值*(RANK(數值,數值)<=G1))
複製儲存格G3,貼至儲存格G3:I3。
RANK(數值,數值)<=G1:在 SUMPRODUCT 函數中可以算出數值陣列中每個儲存格的排序。再判斷是否小於或等於儲存格G1。再於 SUMPRODUCT 函數中計算對應的數值總和。

Excel-無條件進位至5的倍數(INT,MOD)

(網友提問)在 Excel 的工作表中有一個數值清單,如何將數值取無條件進位至5的倍數?(參考下圖)
Excel-無條件進位至5的倍數(INT,MOD)

【公式設計與解析】
儲存格B2:
=INT(A2/10)*10+(MOD(A2,10)>5)*10+(MOD(A2,10)>0)*(MOD(A2,10)<=5)*5
(1) INT(A2/10)*10
利用 INT 函數將儲存格A2的數值中的個位數去除(變成 0)
(2) (MOD(A2,10)>5)*10
利用 MOD 函數取得個位數,並且判斷是否大於 5,若是,則傳回『10』,否則傳回 0。
(3) (MOD(A2,10)>0)*(MOD(A2,10)<=5)*5
利用 MOD 函數取得個位數,並且判斷是否大於 0 且小於或等於 5,若是,則傳回『5』,否則傳回 0。
將(1)+(2)+(3),即為所求。

Excel-根據每日上、下班時間計算整月薪資(SUMPRODUCT,INT)

(網友提問)在 Excel 中有一個每日上班和下班的打卡記錄,以每30分採計(未達30分不採計),如何根據這些數據計算薪資總額?
參考下圖,上班時刻10:11、下班時刻10:57,以每1分計是46分,若以每30分計是1。
Excel-根據每日上、下班時間計算整月薪資(SUMPRODUCT,INT)

【公式設計與解析】
儲存格I2:=SUMPRODUCT(INT((C2:C32-B2:B32)*24*60/30))*I1
(1) INT((C2:C32-B2:B32)*24*60/30)
在 Excel 中是以 1 來表示 1 天,所以:
1 小時是 1/24、1 分是 1/24/60、1 秒是 1/24/60/60
運算式:*24*60/30,可以將分鐘數換算為幾個30分鐘,再利用 INT 函數取除法的『商』,即可將未滿30分鐘者不採計。

(2) SUMPRODUCT(INT((C2:C32-B2:B32)*24*60/30))
在 SUMPRODUCT 函數中可以計算 C2:C32-B2:B32 換算為幾個30分鐘的總和
(即(C2-B2)換算為30分+(C3-B3)換算為30分+…+(C32-B32)換算為30分)。

(3) SUMPRODUCT(INT((C2:C32-B2:B32)*24*60/30))*I1
將 SUMPRODUCT 函數的傳回值乘上薪資,即為薪資總額。

【額外說明】
上圖中的E欄和F欄利用數值格式設定為「[m]」,可以顯示為「分」,但此數值只能拿來參考,無法取來運算。(例如:SUM(F2:F32)的結果並不是真的人眼看到的F欄數值的總和)

【延伸練習】
如果你是要取工作時間總和(累計),再以每30分採計(未達30分不採計)來計算薪資總額?
Excel-根據每日上、下班時間計算整月薪資(SUMPRODUCT,INT)
公式:
儲存格I2:=INT(SUMPRODUCT((C2:C32-B2:B32))*24*60/30)*I1

2017年12月13日 星期三

Excel-日期轉換並計算相差日數(SUBSTITUTE,RIGHT,MID,LEFT)

(網友提問)在 Excel 的工作表中有一個原始日期清單,其格式為105.07.03,如何轉換為1050703,並且能計算二個日期相差的日數?
參考下圖,利用轉換後的日期,計算上下兩個儲存格相差的日數。
Excel-日期轉換並計算相差日數(SUBSTITUTE,RIGHT,MID,LEFT)

【公式設計與解析】
1. 轉換日期格式
儲存格C2:=SUBSTITUTE(A2,".","")
利用 SUBSTITUE 函數將儲存格A2中的『.』取代為『』(空白),相當於刪除『.』。

2. 計算轉換為的兩個日期相差的日數
儲存格D3:=DATE(LEFT(C3,3)+1911,MID(C3,4,2),RIGHT(C3,2))-
DATE(LEFT(C2,3)+1911,MID(C2,4,2),RIGHT(C2,2))
其中:DATE(LET(C3,3)+1911,MID(C3,4,2),RIGHT(C3,2))
LEFT(C3,3)+1911:利用 LEFT 函數取出儲存格C3內容的第1~3碼,即為民國年,再加上 1911,即可轉換為西洋年。
MID(C3,4,2):利用 MID 函數取出儲存格C3內容的第4~5碼,即為月。
RIGHT(C3,2):利用 RIGHT 函數取出儲存格C3內容的第6~7碼,即為日。
將以上三個年月日的參數置入 DATE 函數即可取得日期的數值。
將兩個日期的數值相減,即可得相距的日數。

2017年12月10日 星期日

手機利用Google的Files Go執行檔案對傳

Google 推出的 Files Go App,可以協助你清理手機儲存空間,其中內含一個不錯的工具可以用來在兩隻手機之間傳輸檔案,而且在沒有網際網路連線的環境下還是可行(沒有數據連線或WiFi連線也能分享檔案)。
在連線時 Files Go 會自動開啟你的手機藍牙,並且會對連線加密。所以連線手機的傳輸距離有一定的限制。
兩隻手機都要先安裝 Files Go,Files Go by Google:Google Play 下載
Files Go 可以傳輸各種檔案格式,包含應用程式也可以,例如A手機中已安裝的 App,也可以直接傳輸到另一隻B手機中安裝。
在 Files Go App 中切換至「檔案」之下,即可看到:傳送和接收。
手機利用Google的Files Go執行檔案對傳
以下用 vincent 和 lib 兩隻手機為例來使用 Files Go 傳輸檔案。
vincent:點選「傳送」,顯示「請你的好友開啟應用程式,然後輕觸 [接收]」。
(參考下圖左)。
lib:出現「正在等待傳送者」(參考下圖右)。
手機利用Google的Files Go執行檔案對傳 手機利用Google的Files Go執行檔案對傳
vincent:顯示「正在與lib連線」,正在產生連線ID。(參考下圖左)
lib:顯示「vincent想建立連線」。(參考下圖右)
lib:點選「連線」。(參考下圖右)
手機利用Google的Files Go執行檔案對傳 手機利用Google的Files Go執行檔案對傳
lib:顯示「正在與vincent連線」。(參考下圖左)
lib:顯示「已連線,等待檔未中…」。(參考下圖右)
手機利用Google的Files Go執行檔案對傳 Screenshot_20171210-221116_resize
vincent:選取一個檔案,並點選「傳送」。(參考下圖左)
vincent:檔案立即傳送,顯示「vincent傳送 1 檔案給 lib」。(參考下圖右)
手機利用Google的Files Go執行檔案對傳 手機利用Google的Files Go執行檔案對傳
vincent:可繼續傳送檔案給 lib。(參考下圖左和右)
手機利用Google的Files Go執行檔案對傳 手機利用Google的Files Go執行檔案對傳
相同的,因為連線已經建立了,所以:
lib:也可傳送檔案給 vincent。(參考下圖左和右)
手機利用Google的Files Go執行檔案對傳 手機利用Google的Files Go執行檔案對傳
利用 Files Go 接收的檔案位於手機系統的「Files Go」資料夾之下,其中有二個子資料夾,分別存放圖片和文件:Files Go Docs 和 Files Go Images。
手機利用Google的Files Go執行檔案對傳 手機利用Google的Files Go執行檔案對傳

2017年12月8日 星期五

Excel-根據同一欄有資料的儲存格對應標題依序顯示(OFFSET,COLUMN)

(網友提問)在 Excel 的工作表有下圖(上)的資料表,如何轉換為下圖(下)的資料表。
參考下圖,在每個姓名列中,要將有數字的儲存格,對照日期名稱後依序列在同一列中。
Excel-根據同一欄有資料的儲存格對應標題依序顯示(OFFSET,COLUMN)

【公式設計解析】
儲存格B13:{=IFERROR(OFFSET($B$1,0,SMALL(IF($B2:$K2<>"",
COLUMN($B2:$K2),""),COLUMN(A:A))-2),"")}
這是陣列公式,輸入完成要按 Ctrl+Shift+Enter 鍵,Excel 會自動加「{}」。
複製儲存格B13,貼至儲存格B13:K20。
(1) IF($B2:$K2<>"",COLUMN($B2:$K2),"")
判斷儲存格B2:K2的內容中,如果不是空白內容,則傳回所在的欄號,否則傳回空字串。
(2) SMALL(第(1)式,COLUMN(A:A))
根據第(1)式傳回的欄號,利用 SMALL 函數由小至小依序取出。當公式向右複製時,COLUMN(A:A)=1→COLUMN(B:B)=2→COLUMN(C:C)=3→...。
(3) OFFSET($B$1,0,第(2)式-2)
根據第(2)式取出的欄號,代入 OFFSET 函數中,取出對應的儲存格內容。
(4) IFERROR(第(3)式,"")
當公式向右複製時,第(2)式可能會傳回錯誤訊息,所以利用 IFERROR 函數將錯誤訊息顯示為空白。

Excel-超連結到另一個工作表的連續儲存格(HYPERLINK)

(讀者提問)在 Excel 中如果想要由一個工作表超連結到另一個工作表的指定儲存格,該如何處理?
如下圖,在「引用」工作表中要直接超連結到「來源」工作表中的對應儲存格,公式如何處理?
Excel-超連結到另一個工作表的連續儲存格(HYPERLINK)

【公式設計與解析】
儲存格A1:=HYPERLINK("#來源!"&ADDRESS(ROW(1:1),COLUMN(A:A)),
"來源:"&ADDRESS(ROW(1:1),COLUMN(A:A)))
複製儲存格A1,貼至儲存格A1:C10。
在此利用 HYPERLINK 函數即可完成!HYPERLINK 函數有二個參數:
Link_location:"#來源!"&ADDRESS(ROW(1:1),COLUMN(A:A))
Friendly_name:"來源:"&ADDRESS(ROW(1:1),COLUMN(A:A))
其中利用 ROW 函數向下複製時:
ROW(1:1)=1→ROW(2:2)=2→ROW(3:3)=3→...。
其中利用 COLUMN 函數向右複製時:
COLUMN(A:A)=1→COLUMN(B:B)=2→COLUMN(C:C)=3→...。
特別注意公式中使用『#』的位置,其中「來源」是工作表名稱。

【相關說明】
關於 HYPERLINK 函數之參數的說明:
Link_location:開啟之文件的路徑和檔案名稱。可以參照文件中的位置,也可以參照 Microsoft Word 文件中的書籤。路徑可以指向儲存在硬碟上的檔案、伺服器上的通用命名慣例 (UNC) 路徑,或是網際網路或內部網路上的統一資源定位器 (URL) 路徑。
Friendly_name:在儲存格中顯示的捷徑文字或數值。

2017年12月7日 星期四

Excel-將數列依分組人數自動給予編號(INT,ROW)

(網友提問)在 Excel 的工作表中,假如要依分組人數給予分組編號,該如何處理?
參考下圖,第一列是分組數,要自動產生分組號碼。
Excel-將數列依分組人數自動給予編號(INT,ROW)

【公式設計與解析】
儲存格C2:=INT((ROW(1:1)-1)/C$1)+1
先利用 ROW 函數來產生 1, 2, 3, 4, … 數列。
ROW(1:1)=1→ROW(2:2)=2→ROW(3:3)=3→ROW(4:4)=1→...。
再利用 INT 函數取得除以分組數的『商數』。
注意其中:「ROW(1:1)-1」和最後的「+1」的小技巧。

Excel-計算隔2天日期並跳過星期六日(WEEKDAY)

(網友提問)如果想要根據在 Excel 工作表中的日期清單,將每個日期延後2天,但是必須跳過星期六、日,該如何處理?
這個問題很常見,例如:要計算不包含六、日的 2 個工作天的日期等。(參考下圖)
Excel-計算隔2天日期並跳過星期六日(WEEKDAY)

【公式設計與解析】
儲存格D2:=A2+2+(WEEKDAY(A2+2,2)>5)*(8-WEEKDAY(A2+2,2))
(1) A2+2
用以計算 2 天後的日期。
(2) WEEKDAY(A2+2,2)>5
利用 WEEKDAY 函數來找出日期對應是星期幾,在本例中使用參數 2,表示傳回值 1~7 對應至星期一~星期日。所以如果傳回值大於 5,表示該日期是星期六或星期日。公式會傳回 TRUE/FALSE
Excel-計算隔2天日期並跳過星期六日(WEEKDAY)
(3) 8-WEEKDAY(A2+2,2)
WEEKDAY(A2+2,2) 的傳回值為 1~7,8-WEEKDAY(A2+2,2)的傳回值是 7~1。
(4) (WEEKDAY(A2+2,2)>5)*(8-WEEKDAY(A2+2,2))
該公式在儲存格A2日期 2 天後為星期六時加 2 天,若為星期日則加 1 天。

2017年12月4日 星期一

Excel-自動產生月曆並且標示星期六日(TEXT)

(網友提問)如何在 Excel 的工作中,利用輸入年和月後,自動產生該月的月曆(標示星期幾),並且能將星期六、日加以標示,該如何處理?
參考下圖,當年輸入2019、月輸入10後,自動產生該月各日是星期幾,並且將所有的星期六日儲存格用不同色彩標示。
Excel-自動產生月曆並且標示星期六日(TEXT)

【公式設計與解析】
1. 依年月日產生星期幾
儲存格B3:=RIGHT(TEXT(DATE($A$2,$B$2,B3),"[$-zh-TW]aaa;@"),1)
(1) DATE($A$2,$B$2,B3)
利用 DATE 函數取得年月日的日期。
(2) TEXT(DATE($A$2,$B$2,B3),"[$-zh-TW]aaa;@")
將日期代入 TEXT 函數,並依『[$-zh-TW]aaa;@』格式顯示。(週一、週二、…)
(3) RIGHT(TEXT(DATE($A$2,$B$2,B3),"[$-zh-TW]aaa;@"),1
利用 RIGHT 函數取得最右邊一個字,即為一、二、…、六、日。

2. 設定星期六日的格式
如圖,選取儲存格B5:AF14(所有黃色儲存格),設定格式化的條件的規則:
規則類型:使用公式來決定要格式哪些儲存格。
規則說明:=WEEKDAY(DATE($A$2,$B$2,B$3),2)>5
Excel-自動產生月曆並且標示星期六日(TEXT)
在 WEEKDAY 函數中使用參數 2,星期一~星期日對應傳回值 1~7,所以傳回值 6 和 7 為假日(>5)。
Excel-自動產生月曆並且標示星期六日(TEXT)

【延伸學習】
在依年月日產生星期幾的公式中使用參數「[$-zh-TW]aaa;@」,是如何產生的呢?你可以由以下管道取得。
先選取一個日期,再進入「儲存格格式」設定中的日期部分,然後選取「日期/週三」。
image
再切換至「自訂」,即可取得參數設定。
image

2017年12月2日 星期六

Excel-在一段範圍中比對符合的資料(SUMPRODUCT,OFFSET)

(讀者提問)在 Excel 的工作表中有個材質和價格的清單,其中的價格依最小值和最大值之間的範圍而定。如何依數值位於的範圍內對應的材質以求得價格?
以下圖為例,材質「ZD」的數值17是位於 6.1~25.0 之間,所以對應的價格為 260。
Excel-在一段範圍中比對符合的資料(SUMPRODUCT,OFFSET)

【公式設計與解析】
選取儲存格A1:D13,按 Ctrl+Shift+F3 鍵,勾選「頂端列」,定義名稱:
材質、最小值、最大值、價格。
儲存格H2:=OFFSET(D1,SUMPRODUCT((材質=F2)*((G2>=最小值)*
(G2<=最大值))*ROW(價格))-1,0)
條件一:(材質=F2)
在 SUMPRODUCT 函數中,判斷「材質」儲存格範圍和儲存格F2比對的結果,傳回 TRUE/FALSE 陣列。
條件二:(G2>=最小值)*(G2<=最大值)
在 SUMPRODUCT 函數中,判斷儲存格G2的內容是否介於最大值儲存格範圍和最小值儲存格範圍之間,傳回 TRUE/FALSE 陣列。
其中 (材質=F2)*((G2>=最小值)*(G2<=最大值)) 之間的『*』運算子,相當於執行邏輯 AND 運算。
在 SUMPRODUCT 函數中的(材質=F2)*((G2>=最小值)*(G2<=最大值))*ROW(價格),其中ROW(價格)會傳回價格儲存格範圍的每個儲存格列號。而最後一個『*』運算子,乃是執行乘法運算。運算時的 TRUE/FALSE 陣列會轉換為 1/0 陣列,公式最後會傳回符合條件者的列號。
Excel-在一段範圍中比對符合的資料(SUMPRODUCT,OFFSET)
將上式代入 OFFSET 函數,即可查得符合條件者的價格了。

2017年12月1日 星期五

Excel-依抽籤折扣數計算價錢(VLOOKUP,CHOOSE,MATCH)

(網友提問)在 Excel 的工作表中有一個產品編號和特賣價的對照表,如果選取一個「抽籤折扣(共有三種:95折、90折、85折)」,再依購買數量來計算結帳價,該如何處理?
Excel-依抽籤折扣數計算價錢(VLOOKUP,CHOOSE,MATCH)

【公式設計與解析】
抽籤折扣欄位的下拉式清單是利用資料驗證功能來製作:
Excel-依抽籤折扣數計算價錢(VLOOKUP,CHOOSE,MATCH)

儲存格D2:=VLOOKUP(A2,$G$2:$H$10,2,FALSE)*CHOOSE(MATCH(C2,
{"95折","90折","85折"},0),0.95,0.9,0.85)
(1) 找出特賣價:VLOOKUP(A2,$G$2:$H$10,2,FALSE)
根據儲存格A2的內容(產品編號),利用 VLOOKUP 函數查詢對應的特賣價。

(2) 計算結帳價:CHOOSE(MATCH(C2,{"95折","90折","85折"},0),0.95,0.9,0.85)
MATCH(C2,{"95折","90折","85折"},0):根據儲存格C2的內容(抽籤折扣)查詢第幾種特價。
根據 MATCH 函數的傳回值,於 CHOOSE 函數對應傳回一個折扣數值。其中「95折、90折、85折」對照折扣「0.95、0.9、0.85」。

2017年11月28日 星期二

Word-文件中只開放部分內容可以編輯

當你建立了一個 Word 文件,如果想要兼顧可以輸入內容,又不想某些文字內容被修改,要如何處理?
參考下圖,本文件只允許黃色區域可以輸入/修改資料,其他區域不能被編輯。
Word-文件中只開放部分內容可以編輯
要解決這個問題,必須要藉助文件「限制編輯」功能!
首先,你得先開啟「開發人員」功能表。
接著,在文件中選取你允許使用者輸入資料的位置。
然後,在「限制編輯」的功能窗格中,勾選「文件中僅允許此類型的編輯方式:不允許修改制(唯讀)」。
在「例外(選用)」中選取開放給那些人。預設值為:每個人。
最後,按一下「是,開始強制保護」。你必須輸入二次相同的保護密碼。
Word-文件中只開放部分內容可以編輯
使用者將只能在開放的區域中輸入資料。
Word-文件中只開放部分內容可以編輯
你可以勾選或取消勾選「在我可以編輯的區域加上醒目標示」,即可切換顯示黃色標示。
Word-文件中只開放部分內容可以編輯
如果你要開放編輯的區域分佈在多個區域,則可以按著 Ctrl 鍵加上滑鼠拖曳選取。
Word-文件中只開放部分內容可以編輯
即可設定多個可編輯區域:
Word-文件中只開放部分內容可以編輯

Excel-求正數最小值和負數最大值(陣列公式)

在 Excel 的工作表中有一個數值清單,如何求正數最小值和負數最大值?
Excel-求正數最小值和負數最大值(陣列公式)

【公式設計與解析】
選取儲存格A1:A21,按 Ctrl+Shift+F3 鍵,定義名稱:數值。
1. 正數最小值
公式:{=MIN(IF(數值>0,數值,""))}
以上為陣列公式,輸入完成要按 Ctrl+Shift+Enter 鍵,Excel 會自動加上「{{}」。

2. 負數最大值
公式:{=MAX(IF(數值<0 p="">
以上為陣列公式,輸入完成要按 Ctrl+Shift+Enter 鍵,Excel 會自動加上「{{}」。

Excel-對符合條件者排序(SUMPRODUCT)

(網友提問)當你在 Excel 的工作表中對一個成績清冊的某個欄位排序時,如果想要只對某些符合條件的資料來排序,該如何處理?
如下圖,若本例設定只顯示英文超過 88 者的排名,並且標示前三名。
Excel-對符合條件者排序(SUMPRODUCT)

【公式設計與解析】
先選取儲存格B1:E26,按Ctrl+Shift+F3 鍵,勾選「頂端列」,定義名稱:國文、英文、數學、總分。
1. 計算原排名
儲存格F2:=RANK(E2,總分)
複製儲存格F2,貼至儲存格F2:F26。
2. 計算符合條件的排名
儲存格E2:=IF(C2>85,SUMPRODUCT((英文>88)*(總分>E2))+1,"")
利用雙條件:(英文>88)*(總分>E2),讓 SUMPRODUCT 函數計算由第一個儲存格(E2)開始至每個儲存格的範圍中,大於本身儲存格的個數。(模擬 RANK 功能)
3. 將前3名標示星號
若要將前3名標示星號,則在設定好上述公式後,再透過設定格式化的條件來處理。
勾選「只顯示圖示」。(表示不顯示數值)
設定 >=4 時不顯示圖示,否則顯示星號。
Excel-對符合條件者排序(SUMPRODUCT)

2017年11月27日 星期一

Excel-初探2016版的新增圖表

Excel 的圖表工具是實用的好幫手!在 Excel 2016 中又新增了六種實用的圖表工具。最近有試著來練習看看。
Excel-初探2016版的新增圖表

1. 矩形式樹狀結構圖
矩形會依數值大小而定,同一類別給予相同色彩,總和大者在左邊,單項大者在上方。
Excel-初探2016版的新增圖表

2.放射環狀圖
相同類別給予相同色彩,並依數值大小的順序顯示。
Excel-初探2016版的新增圖表

3.瀑布圖
顯示增加/減少的概念呈現,圖中也含有累計的概念。
image

4.長條圖
將所有資料予以分組(依最大和最小之間分組,並可自訂組數),顯示次數分配圖。
image

5.盒鬚圖
統計圖中會依分組標示:最大值、75%四分位數、50%四分位數、25%四分位數、最小值和平均數等。
image

6. 3D地圖
結合地圖(資料表中必須要有地圖位置名稱)在其中顯示統計圖表,並可以錄製視訊。
image
image

檢視其他文章

好康東東