2017年9月29日 星期五

Word-在文件中建立多個同步更新的文字內容

網友問到:如何在 Word 文件中建立可以同步更新的文字內容?
例如:在下圖中,第一個姓名(王大明)和電話(0987654321)被修改時,其後的多個姓名、電話也能同步被更新。
Word-在文件中建立多個同步更新的文字內容
如果在 Excel 中執行這個工作,就十分的容易了,在 Word 中必須使用「功能變數」來處理。做法如下:
1. 先選取第一個姓名(本例為『王小明』)。
2. 建立書籤,並且命名為『name』,然後按一下[新增]按鈕。
3. 相同做法建立電話的書籤,並且命名為『phone』。
Word-在文件中建立多個同步更新的文字內容
4. 在姓名欄位下,選取功能變數名稱:Ref,再選取書籤名稱:name。
4. 在電話欄位下,選取功能變數名稱:Ref,再選取書籤名稱:photo。
Word-在文件中建立多個同步更新的文字內容
如果你更改了姓名和電話,此時,其他位置的相同內容一時間沒有同步更新。
Word-在文件中建立多個同步更新的文字內容
你只要選取要更新的內容(或按 Ctrl+A),按一下 F9 鍵,隨即會同步更新。
Word-在文件中建立多個同步更新的文字內容

Excel-在活頁簿的2個工作表中標示相同內容的儲存格

網友問到:在 Excel 中,如何讓活頁簿裡的 2 個工作表比對內容,並且將相同內容的儲存格以相同色標示?
例如以下圖中的表 1 和表 2,不同工作表中的相同儲存格,若是相同內容,則以粉紅色底色標示。
表1:
Excel-在活頁簿的2個工作表中標示相同內容的儲存格
表2:
Excel-在活頁簿的2個工作表中標示相同內容的儲存格

【公式設計與解析】
1.選取想要的儲存格
2.進入「設定格式化的條件」設定:
規則類型:使用公式來決定要格式化哪些儲存格
規則說明:=A1=表2!A1(相當於=表1!A1=表2!A1)
格式:填滿粉紅色底色
Excel-在活頁簿的2個工作表中標示相同內容的儲存格

在表 2 工作表中:
1.選取想要的儲存格
2.進入「設定格式化的條件」設定:
規則類型:使用公式來決定要格式化哪些儲存格
規則說明:=A1=表1!A1(相當於=表1!A1=表2!A1)
格式:填滿粉紅色底色
Excel-在活頁簿的2個工作表中標示相同內容的儲存格

2017年9月27日 星期三

Excel-指定同房者的分房作業(MATCH,OFFSET)

網友提問一個有趣的題目:在 Excel 的資料表中,如何根據互相指定同房人員來自動分配房間?
參考下圖,B欄是每個人的姓名,C欄是這個人指定的同房人員,根據這兩欄的資訊要自動分好房間,讓指定的兩人自動分在同一間。
Excel-指定同房者的分房作業(MATCH,OFFSET)

【公式設計與解析】
為了讓讀者更清楚公式,所以使用了輔助欄位。
1. 找出A的同房者B所指定的同房人員C
儲存格D2:=OFFSET($B$1,MATCH(C2,$B$2:$B$23,0),1)
(1) MATCH(C2,$B$2:$B$23,0)
利用 MATCH 函數,找出儲存格C2在儲存格範圍B2:B23的位置,傳回一個數值。
(2) OFFSET($B$1,MATCH(C2,$B$2:$B$23,0),1)
利用 OFFSET 函數根據第(1)式傳回的位置找到對應的儲存格內容(人員C)。

2. 判斷人員C是否和人員A相同
判斷人員C是否和人員A相同,若相同,表示互相指定(同房),若不相同,表示未互相指定(不能同房)
儲存格E2:=IFERROR(IF(D2=B2,"V","X "&B2),"")
若傳回『V』,表示互相指定(同房),若傳回『X』,表示未互相指定(不能同房)。
若有錯誤訊息,則以 IFERROR 函數將其顯示為空白。

3. 找出人員A和人員B的位置,並取最小值
儲存格F2:
=IF(E2="V",MIN(MATCH(B2,$B$2:$B$23,0),MATCH(C2,$B$2:$B$23,0)),"")
(1) MATCH(B2,$B$2:$B$23,0)
找出儲存格B2內容在儲存格B2:B23中的位置,傳回一個數值。
(2) MATCH(C2,$B$2:$B$23,0)
找出儲存格C2內容在儲存格C2:CB23中的位置,傳回一個數值。
(3) MIN(MATCH(B2,$B$2:$B$23,0),MATCH(C2,$B$2:$B$23,0))
比較第(1)式和第(2)式的傳回值,並以 MIN 函數取其最小值。

4. 執行分房作業
儲存格G2:=IF(F2<>"","A0"&COUNTIF($F$2:$F$23,"<="&F2)/2,"")
假設房間號碼是A01~A20。
COUNTIF($F$2:$F$23,"<="&F2)/2:利用 COUNTIF 函數計算由第一個儲存格F2起始的儲存格範圍內和儲存格F2相同者的『數量』。再根據這個數量來產生房間的編號。

2017年9月24日 星期日

Excel-在儲存格中輸入資料時的提醒與限制

網友提問:在 Excel 中如何在儲存格中輸入資料時給予提醒或加以限制?
例如:參考下圖,當在A欄分別輸入甲、乙、丙、丁時,當點選B,C,D,E各欄儲存格時,依下圖指示給予提醒或限制。
Excel-在儲存格中輸入資料時的提醒與限制
通常要自動改變儲存格底色是使用「設定格式化的條件」功能;而要顯示提醒或限制的文字,則可以使用「資料驗證」功能。
資料表預設值如下:
Excel-在儲存格中輸入資料時的提醒與限制
當儲存格A2:A5有資料輸入時,部分儲存格要改變底色,當選取其中一個儲存格時,顯示提示輸入資料文字。
Excel-在儲存格中輸入資料時的提醒與限制
先來設定提醒色彩。選取儲存格B2,設定其格式化的條件。並設定:
規則類型:使用公式來決定要格式化的哪些儲存格
規則:=LEN($A2)>0
格式:粉紅色儲存格底色
image
再來,設定提醒文字。
選取儲存格B2,設定其資料驗證。並設定:
資料驗證準則:自訂
公式:=LEN(A2)
Excel-在儲存格中輸入資料時的提醒與限制
接著,在[提示訊息]標籤下設定提示訊息:請輸入資料。
Excel-在儲存格中輸入資料時的提醒與限制
最後,複製儲存格B2,貼至上圖的粉紅色底色儲存格。
再來,要設定儲存格限制輸入文字。
Excel-在儲存格中輸入資料時的提醒與限制
選取儲存格D2,設定其資料驗證。並設定:
資料驗證準則:自訂
公式:=NOT(LEN(A2))
Excel-在儲存格中輸入資料時的提醒與限制
接著,在[提示訊息]標籤下設定提示訊息:不可輸入資料。
Excel-在儲存格中輸入資料時的提醒與限制
最後,複製儲存格D2,貼至上圖的藍色底色儲存格。
當在功能限制的儲存格輸入資料時,會有警告訊息:
Excel-在儲存格中輸入資料時的提醒與限制

2017年9月22日 星期五

Excel-取出單位前的數值(FIND,MID,SUBSTITUTE)

回答網友提問:如下圖的 Excel 工作表,如何取出『包/盒』和『盒/箱』前的數字?
image

1. 計算『包/盒』數量
儲存格B2:=MID(A2,1,FIND("包",A2)-1)
FIND("包",A2):利用 FIND 函數找尋『包』在儲存格中第 1 次出現的位置。
利用上式的傳回值,透過 MID 函數取得儲存格最前面的數字。

2. 計算『盒/箱』數量
儲存格C2:=MID(SUBSTITUTE(A2,"盒/箱",""),FIND(";",A2)+1,99)
SUBSTITUTE(A2,"盒/箱",""):將儲存格A2中的內容去除字串『盒/箱』(將『盒/箱』以空字串取代)。
FIND(";",A2):利用 FIND 函數找尋『;』在儲存格中出現的位置。
利用上式的傳回值,透過 MID 函數取得儲存格字串『盒/箱』前的數字。其中的參數  99,只是一個很大的隨機數字,用以取得『;』之後的所有字串(不包含『盒/箱』)。

2017年9月21日 星期四

Excel-調整金額顯示格式(TEXT,MID)

參考下圖,網友問到:如何在 Excel 中將一個原始金額調整其格式如下圖右?
在下圖中,要將一個數值轉換為金額的表示方式,其中億為 2 位數、萬為 4 位數、元為 4 位數,並且要套用千分位符號。
調整金額顯示格式(TEXT,MID)

【公式設計與解析】
儲存格C2:
=IF(A2>10^8,TEXT(MID(TEXT(A2,"0000000000"),1,2),"##")&"億","")&
IF(A2>10^4,TEXT(MID(TEXT(A2,"0000000000"),3,4),"#,###")&"萬","")&
TEXT(MID(TEXT(A2,"0000000000"),7,4),"#,###")&"元"
複製儲存格C2,貼至儲存格C2:C11。
(1) IF(A2>10^8,TEXT(MID(TEXT(A2,"0000000000"),1,2),"##")&"億","")
TEXT(A2,"0000000000"):將儲存格A2的內容補足 10 位元。
MID(TEXT(A2,"0000000000"),1,2):取出補足 10 位元的儲存格A2的 1~2 位元。
在 IF 函數中判斷條件:A2>10^8 是否成立(是否超過 1 億),再執行該段公式。

(2) IF(A2>10^4,TEXT(MID(TEXT(A2,"0000000000"),3,4),"#,###")&"萬","")
MID(TEXT(A2,"0000000000"),3,4):取出補足 10 位元的儲存格A2的第 3~6 位元。
在 IF 函數中判斷條件:A2>10^4 是否成立(是否超過 1 萬),再執行該段公式。
在 TEXT 函數中使用參數『#,###』,用以設定顯示千分位格式。

(3) TEXT(MID(TEXT(A2,"0000000000"),7,4),"#,###")&"元"
MID(TEXT(A2,"0000000000"),7,4):取出補足 10 位元的儲存格A2的第 7~10 位元。
在 TEXT 函數中使用參數『#,###』,用以設定顯示千分位格式。

2017年9月19日 星期二

Excel-將數字金額轉換為國字金額(TEXT,MID,COLUMN,INT)

網友問到:在 Excel 中如何如下圖將數字金額轉換為國字金額?
例如:將 472 轉換為肆佰柒拾貳元。
Excel-將數字金額轉換為國字金額(TEXT,MID,COLUMN,INT)
【公式設計與解析】
儲存格F1:
=TEXT(MID(TEXT($C1,"000"),INT(COLUMN(A:A)/2)+1,1),"[DBNum2]")
複製儲存格F1,分別貼至儲存格H1和儲存格J1。
(1) TEXT($C1,"000")
不管儲存格C1中的數字為幾位數,全部轉換為 3 位數,前面補 0。
(2) INT(COLUMN(A:A)/2)+1,1)
COLUMN(A:A)=1,向右複製時,COLUMN(A:A)=1→COLUMN(B:B)=2→COLUMN(C:CA)=3→....。
INT(COLUMN(A:A)/2)+1,1)=1,向右複製每間隔兩欄貼上,可得 2, 3, 4, …。
(3) TEXT(第(1)式, 第(2)式, "[DBNum2]")
使用參數 [DBNum2],可以將數字顯示為『一、二、三、四、五、六、七、八、九、零』。
公式自動產生,儲存格H1:
=TEXT(MID(TEXT($C1,"000"),INT(COLUMN(C:C)/2)+1,1),"[DBNum2]")
公式自動產生,儲存格J1:
=TEXT(MID(TEXT($C1,"000"),INT(COLUMN(E:E)/2)+1,1),"[DBNum2]")

如果你要增加數值的位元數,則仿照以上的公式即可完成。
例如:將 8615 轉換為捌千陸佰壹拾伍元。
Excel-將數字金額轉換為國字金額(TEXT,MID,COLUMN,INT)
儲存格F1:
=TEXT(MID(TEXT($C1,"0000"),INT(COLUMN(A:A)/2)+1,1),"[DBNum2]")
其實公式完全一模一樣,複製儲存格F1,分別貼至儲存格H1和儲存格J1和儲存格L1。

2017年9月17日 星期日

Excel-找出間隔欄位資料的最大值(COLUMN,OFFSET,MATCH,陣列公式)

參考下圖,網友問到如何在 Excel 的工作表中找出間隔欄位資料的最大值?
例如:在蘋果那一列找出最大的公斤數(500),並且求得最大公斤數對應的價格(24)。
Excel-找出間隔欄位資料的最大值(COLUMN,OFFSET,MATCH,陣列公式)

【公式計與解析】
1. 找出最大公斤數
儲存格C8:{=MAX((MOD(COLUMN(C3:K3),2)=1)*(C3:K3))}
這是陣列公式,輸入完成要按 Ctrl+Shift+Enter 鍵,Excel 會自動加「{}」。
複製儲存格C8,貼至儲存格C8:C9。
(1) MOD(COLUMN(C3:K3),2)=1
利用 COLUMN 函數來取得儲存格C3:K3範圍中每一個儲存格的欄數。再利用 MOD 函數其每個欄數除以 2 的餘數,若餘數為『1』,表示為 C, E, G, I, K 欄。
(2) (MOD(COLUMN(C3:K3),2)=1)*(C3:K3))
取得 C, E, G, I, K 欄的公斤數。
(3) MAX((MOD(COLUMN(C3:K3),2)=1)*(C3:K3))
將取得 C, E, G, I, K 欄的公斤數,利用 MAX 函數求得最大值。

2. 找出最大公斤數對應的價格
儲存格B8:=OFFSET(B3,0,MATCH(C8,C3:K3,0)-1)
複製儲存格B8,貼至儲存格B8:BC9。
(1) MATCH(C8,C3:K3,0)
利用 MATCH 函數求得儲存格C8的內容在儲存格C3:K3範圍裡的位置,傳回一個數值。
(2) OFFSET(B3,0,MATCH(C8,C3:K3,0)-1)
利用 OFFSET 函數代入第(1)式傳回的數值,找出對應的儲存格內容。

2017年9月16日 星期六

Excel-依數值區間查詢分級(VLOOKUP)

網友問到:如何在 Excel 的工作表中,依數值區間查詢分級的作法?
分級方式如下:
正常值       男生12~18                  ,女11~15
異常D級     男生10~11.9或18.1~19 ,女生10~10.9或15.1~16
異常C級     男生8~9.9或19.1~20    ,女生8~9.9或16.1~17
網友原本想要使用巢狀 IF 函數,但是我不建議這樣做。
參考下圖,由網友提供的分級方式,先轉換成可以供 VLOOKUP 函數查詢的表格,再使用VLOOKUP 函數建立公式。
如此,會比網友使用巢狀 IF 函數來的好,因為公式比較簡捷,而且分級對照的數值如果變動,只要修改對照表,不用修改公式。
Excel-依數值區間查詢分級(VLOOKUP)

【公式設計與解析】
儲存格B3:=CHOOSE(MATCH(B1,A8:B8,0),VLOOKUP(B2,A9:C15,3,TRUE),
VLOOKUP(B2,B9:C15,2,TRUE))
(1) MATCH(B1,A8:B8,0)
利用 MATCH 函數依據儲存格B1查詢在儲存格A8:B8範圍中的位置。若為男生,則傳回『1』;若為女生,則傳回『2』。
(2) VLOOKUP(B2,A9:C15,3,TRUE)
利用 VLOOKUP 函數依儲存格B2查詢儲存格A9:C15範圍的資料,傳回第 3 欄的結果。
(3) VLOOKUP(B2,B9:C15,2,TRUE)
利用 VLOOKUP 函數依儲存格B2查詢儲存格B9:C15範圍的資料,傳回第 2 欄的結果。
(4) CHOOSE(第(1)式,第(2)式,第(3)式)
利用 CHOOSE 函數,根據第(1)式的傳回值,若為『1』(男生),則執第(2)式;若為『2』(女生),則執第(3)式。

2017年9月15日 星期五

Excel-練習(以國中教育會考成績為例)2(SUMPRODUCT,陣列公式)

讀者根據這篇:
問到:(參考下圖)如果要計算每個學生所獲得 A 有幾個『+』、B 有幾個『+』,該如何處理。
Excel-練習(以國中教育會考成績為例)2(SUMPRODUCT,陣列公式)

【公式設計與解析】
選取儲存格K1:K8,按 Ctrl+Shift+F3 鍵,勾選「頂端列」,定義名稱:等級標示、數量。
儲存格H2:=SUMPRODUCT((LEFT(C2:G2,1)="A")*(等級標示=C2:G2)*數量)
複製儲存格H2,往下各列貼上,即可求得每位學生換算得的總點數。
(1) 條件一:LEFT(C2:G2,1)="A"
在 SUMPRODUCT 函數中,利用 LEFT 函數將儲存格C2:G2取出第 1 個字,判斷是否為『A』。
(2) 條件二:(等級標示=C2:G2)*數量
取得儲存格C2:G2中每個儲存格內容所對照的數量。
如果使用陣列公式,則公式:
儲存格I2:{=SUM((LEFT(C2:G2,1)="A")*(等級標示=C2:G2)*數量)}
陣列公式,輸入完成要按 Ctrl+Shift+Enter 鍵,Excel 會自動加上「{}」。

同理:
儲存格I2:=SUMPRODUCT((LEFT(C2:G2,1)="B")*(等級標示=C2:G2)*數量)
複製儲存格I2,往下各列貼上,即可求得每位學生換算得的總點數。
如果使用陣列公式,則公式:
儲存格I2:{=SUM((LEFT(C2:G2,1)="B")*(等級標示=C2:G2)*數量)}
陣列公式,輸入完成要按 Ctrl+Shift+Enter 鍵,Excel 會自動加上「{}」。

Excel-根據規則建立查詢公式,不使用資料表(SUBSTITUTE,VLOOKUP)

網友提問:如何由下圖右的資料表(或稱規則)來根據PVC管來查詢計算結果。
查詢可以使用資料表,也可以不使用資料表。
Excel-根據規則建立查詢公式,不使用資料表(SUBSTITUTE,VLOOKUP)

【公式設計與解析】
一般的查詢動作,只要提供資料表,透過 VLOOKUP、INDEX、OFFSET 等函數都可以輕易達成。例如:
儲存格B3:=VLOOKUP(A3,E2:F21,2)
但是,其中都需要一個查詢用的資料表。
如果,你觀察你要查詢的內容具有一定的規則,也可以設計公式,不需透過資料表即可獲取結果。例如:
儲存格B3:=SUBSTITUTE(A3,"DB","")*200
本例中,PVC管名稱和計價的對應關係都有一定的規則,所以在此是利用 SUBSTITUTE 函數先將儲存格A3中的『DB』去除(名稱規則),得到一個數字,而該數字再乘上 200(計價規則)。如此,便不需透過資料表來查詢。

Word-將圖片不儲存於於文件中

當你在編輯 Word 文件時,如果插入大量的圖片,每個圖片的尺寸都很大(參考下圖),將會影響文件的檔案大小。是否有不同的做法?
Word-將圖片不儲存於於文件中
或許你也會使用 Word 的「壓縮圖片」功能來讓 Word 的檔案尺寸變小,但也會犧牲了圖片的解析度。
Word-將圖片不儲存於於文件中
你也以試試使用功能數來插入圖片,並且不讓圖片儲存於文件中,而更換圖片時可以不用修改文件。
功能變數位於快速組件中:
Word-將圖片不儲存於於文件中
選取功能變數「IncludePicture」。注意到對話框右側有「功能變數的選項」和「更新時保持原格式」的選項。
Word-將圖片不儲存於於文件中
如果你點選上圖的[功能變數代碼]按鈕,再按[選項]按鈕,即會出現功能變數的參數。
Word-將圖片不儲存於於文件中
在檔案名稱中輸入照片名稱,例如:pic01.JPG,然後勾選:圖形資料不儲存於文件。
Word-將圖片不儲存於於文件中
照片已進入 Word 文件中。
Word-將圖片不儲存於於文件中
調整好大小,並且複製幾個:
Word-將圖片不儲存於於文件中
按 Alt+F9 鍵,顯示功能變數:
Word-將圖片不儲存於於文件中
直接修改功能變數中的檔案名稱:
Word-將圖片不儲存於於文件中
按 Alt+F9 鍵,取消顯示功能變數。參考下圖,雖然圖片都顯示同一點,但是不用緊張。
Word-將圖片不儲存於於文件中
按 Ctrl+A 鍵,全選所有照片,再按 F9 鍵,圖片即會被更新。
Word-將圖片不儲存於於文件中
觀察 Word 文件的檔案大小,是個非常小的尺寸。
Word-將圖片不儲存於於文件中
假設我更換了圖片(相同名稱),則開啟相同的 Word 文件,內容已更被更換。(本例更換 pic01.JPG)
Word-將圖片不儲存於於文件中
有一點必須要提醒:照片和文件的路徑必須要注意,建議放在同一資料夾。

2017年9月11日 星期一

Excel-日期格式轉換(相同日期給予編號)(TEXT,COUNTIF)

網友提問:在 Excel 中的資料表(如下圖),有一組原始的日期清單,如何在相同日期中給予編號,並轉換如下圖右的格式?
Excel-日期格式轉換(相同日期給予編號)(TEXT,COUNTIF)

【公式設計與解析】
儲存格C2:=TEXT(A2,"yyyymmdd")&TEXT(COUNTIF($A$2:A2,A2),"000")
複製儲存格C2,貼至儲存格C2:C23。
(1) TEXT(A2,"yyyymmdd")
利用 TEXT 函數將 yyyy/mm/dd 的日期格式轉換為 yyyymmdd。
(2) COUNTIF($A$2:A2,A2)
利用 COUNTIF 函數計算從第 1 個儲存格開始累計相同內容的數量。
(3) TEXT(COUNTIF($A$2:A2,A2),"000")
將第(2)式的傳回值以格式 3 位數顯示。

2017年9月9日 星期六

Excel-根據數值大小(百分比)顯示漸層色彩

網友問到:在 Excel 的工作表中,想要根據數值大小(百分比)顯示漸層色彩,該如何處理?
參考下圖的C欄和D欄,正確率是以百分比表示,漸層欄位沒有顯示數值。
Excel-根據數值大小(百分比)顯示漸層色彩
1. 首先,在D欄建立一個和C欄內容相同的數值:
Excel-根據數值大小(百分比)顯示漸層色彩
2. 選取儲存格D2:D16。
3. 選取[設定格式化的條件/色階]的「其他規則」選項。
Excel-根據數值大小(百分比)顯示漸層色彩
4. 在[格式樣式]中選取「資料横條」
5. 勾選:僅顯示資料横條。
6. 設定最小值:數值/0;最大值:數值/1。
7. 設定填滿:漸層填滿;色彩:綠色。
Excel-根據數值大小(百分比)顯示漸層色彩
結果如下:
Excel-根據數值大小(百分比)顯示漸層色彩

Excel-根據兩個日期來計算每個時間區間的數量(INT,ROW,HOUR)

網友問到:在 Excel 的工作表裡,如何根據兩個日期來計算每個時間區間的數量。
參考下圖,時間是一日中的 24 個小時的區間,要來計算起迄日期間的每個時間區間數量。
Excel-根據兩個日期來計算每個時間區間的數量(INT,ROW,HOUR)

【公式設計與解析】
儲存格D2:=INT(N($A$5))-INT(N($A$2))+(HOUR($A$2)<=(ROW(1:1)-1))+
(HOUR($A$5)>=(ROW(1:1)-1))
複製儲存格D2,貼至儲存格D2:D25。
(1) INT(N($A$5))-INT(N($A$2))
利用 N 函數取得日期對應的數值,將兩個日期的數值相減,得到相差的天數。
(2) HOUR($A$2)<=(ROW(1:1)-1)
當公式向下複製時,ROW(1:1)=1→ROW(2:2)=2→ROW(3:3)=3→…。
條件:HOUR($A$2)<=(ROW(1:1)-1) ,若成立則傳回 1,若不成立則傳回 0。
(3) HOUR($A$5)>=(ROW(1:1)-1)
條件:HOUR($A$5)>=(ROW(1:1)-1) ,若成立則傳回 1,若不成立則傳回 0。

Windows 10-進入檔案總管時直接顯示本機頁面並且不顯示快速存取內容

當使用 Windows 10 啟動檔案總管時,預設是進入「快速存取」頁面,而快速存取區是記錄最近你使用的檔案和資料夾。有時覺得畫面太複雜而混亂,並且有隱私暴露的問題。如何來調整呢?
Windows 10-進入檔案總管時直接顯示本機頁面並且不顯示快速存取內容
還好,Windows 10 留有開關,讓你切換顯示的內容。
首先,在「快速存取」上按右鍵,並選取「選項」。
Windows 10-進入檔案總管時直接顯示本機頁面並且不顯示快速存取內容
在「隱私權」區中取消勾選:
(1)在[快速存取]中顯示最近使用的檔案
(2)在[快速存取]中顯示最近使用的資料夾
並且按一下「清除」按鈕,將已有的記錄加以消除。
Windows 10-進入檔案總管時直接顯示本機頁面並且不顯示快速存取內容
接著,在[開啟檔案總時以]區中選取:本機,讓啟動檔案總管時直接顯示本機頁面。
Windows 10-進入檔案總管時直接顯示本機頁面並且不顯示快速存取內容
看來清爽多了。
Windows 10-進入檔案總管時直接顯示本機頁面並且不顯示快速存取內容

檢視其他文章

好康東東